Excel VBA: Base64 Encoding, Easy

Base64 encoding and decoding of text is a common requirement, yet Excel and VBA have no native function for doing so.

Here is the most efficient and streamlined method I've conjured to encode text to Base64:

Function EncodeBase64(text$)
    Dim b
    With CreateObject("ADODB.Stream")
        .Open: .Type = 2: .Charset = "utf-8"
        .WriteText text: .Position = 0: .Type = 1: b = .Read
        With CreateObject("Microsoft.XMLDOM").createElement("b64")
            .DataType = "bin.base64": .nodeTypedValue = b
            EncodeBase64 = Replace(Mid(.text, 5), vbLf, "")
        End With
        .Close
    End With
End Function

And the sister function to decode:

Function DecodeBase64(b64$)
    Dim b
    With CreateObject("Microsoft.XMLDOM").createElement("b64")
        .DataType = "bin.base64": .text = b64
        b = .nodeTypedValue
        With CreateObject("ADODB.Stream")
            .Open: .Type = 1: .Write b: .Position = 0: .Type = 2: .Charset = "utf-8"
            DecodeBase64 = .ReadText
            .Close
        End With
    End With
End Function

Note that both of these functions support ASCII and it's extension, Unicode UTF-8.

So now you can easily and efficiently encode even tough text like the following.

யாமறிந்த மொழிகளிலே தமிழ்மொழி போல்

If the above text was in A1, then:

[a2] = EncodeBase64([a1])

...would assign the following text to cell A2:

4K6v4K6+4K6u4K6x4K6/4K6o4K+N4K6kIOCuruCviuCutOCuv+CuleCus+Cuv+CusuCvhyDgrqTgrq7grr/grrTgr43grq7gr4rgrrTgrr8g4K6q4K+L4K6y4K+N

And to return the encoded text back to the original:

[a3] = DecodeBase64([a2])

And cell A3 will contain the original text:

யாமறிந்த மொழிகளிலே தமிழ்மொழி போல்

Again, these functions will work on normal ASCII text as well as Unicode UTF-8. As a side note, realize that worksheet cells will fully display Unicode, but the VBA environment, including the VB Editor, MsgBoxes and Userforms are all ANSI and will not display Unicode.

Let me know your thoughts in the comments.